vdso64.lds.S 3.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149
  1. /*
  2. * This is the infamous ld script for the 64 bits vdso
  3. * library
  4. */
  5. #include <asm/vdso.h>
  6. OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
  7. OUTPUT_ARCH(powerpc:common64)
  8. ENTRY(_start)
  9. SECTIONS
  10. {
  11. . = VDSO64_LBASE + SIZEOF_HEADERS;
  12. .hash : { *(.hash) } :text
  13. .gnu.hash : { *(.gnu.hash) }
  14. .dynsym : { *(.dynsym) }
  15. .dynstr : { *(.dynstr) }
  16. .gnu.version : { *(.gnu.version) }
  17. .gnu.version_d : { *(.gnu.version_d) }
  18. .gnu.version_r : { *(.gnu.version_r) }
  19. .note : { *(.note.*) } :text :note
  20. . = ALIGN(16);
  21. .text : {
  22. *(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
  23. *(.sfpr .glink)
  24. } :text
  25. PROVIDE(__etext = .);
  26. PROVIDE(_etext = .);
  27. PROVIDE(etext = .);
  28. . = ALIGN(8);
  29. __ftr_fixup : { *(__ftr_fixup) }
  30. . = ALIGN(8);
  31. __lwsync_fixup : { *(__lwsync_fixup) }
  32. . = ALIGN(8);
  33. __fw_ftr_fixup : { *(__fw_ftr_fixup) }
  34. /*
  35. * Other stuff is appended to the text segment:
  36. */
  37. .rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  38. .rodata1 : { *(.rodata1) }
  39. .dynamic : { *(.dynamic) } :text :dynamic
  40. .eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
  41. .eh_frame : { KEEP (*(.eh_frame)) } :text
  42. .gcc_except_table : { *(.gcc_except_table) }
  43. .rela.dyn ALIGN(8) : { *(.rela.dyn) }
  44. .opd ALIGN(8) : { KEEP (*(.opd)) }
  45. .got ALIGN(8) : { *(.got .toc) }
  46. _end = .;
  47. PROVIDE(end = .);
  48. /*
  49. * Stabs debugging sections are here too.
  50. */
  51. .stab 0 : { *(.stab) }
  52. .stabstr 0 : { *(.stabstr) }
  53. .stab.excl 0 : { *(.stab.excl) }
  54. .stab.exclstr 0 : { *(.stab.exclstr) }
  55. .stab.index 0 : { *(.stab.index) }
  56. .stab.indexstr 0 : { *(.stab.indexstr) }
  57. .comment 0 : { *(.comment) }
  58. /*
  59. * DWARF debug sections.
  60. * Symbols in the DWARF debugging sections are relative to the beginning
  61. * of the section so we begin them at 0.
  62. */
  63. /* DWARF 1 */
  64. .debug 0 : { *(.debug) }
  65. .line 0 : { *(.line) }
  66. /* GNU DWARF 1 extensions */
  67. .debug_srcinfo 0 : { *(.debug_srcinfo) }
  68. .debug_sfnames 0 : { *(.debug_sfnames) }
  69. /* DWARF 1.1 and DWARF 2 */
  70. .debug_aranges 0 : { *(.debug_aranges) }
  71. .debug_pubnames 0 : { *(.debug_pubnames) }
  72. /* DWARF 2 */
  73. .debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
  74. .debug_abbrev 0 : { *(.debug_abbrev) }
  75. .debug_line 0 : { *(.debug_line) }
  76. .debug_frame 0 : { *(.debug_frame) }
  77. .debug_str 0 : { *(.debug_str) }
  78. .debug_loc 0 : { *(.debug_loc) }
  79. .debug_macinfo 0 : { *(.debug_macinfo) }
  80. /* SGI/MIPS DWARF 2 extensions */
  81. .debug_weaknames 0 : { *(.debug_weaknames) }
  82. .debug_funcnames 0 : { *(.debug_funcnames) }
  83. .debug_typenames 0 : { *(.debug_typenames) }
  84. .debug_varnames 0 : { *(.debug_varnames) }
  85. /DISCARD/ : {
  86. *(.note.GNU-stack)
  87. *(.branch_lt)
  88. *(.data .data.* .gnu.linkonce.d.* .sdata*)
  89. *(.bss .sbss .dynbss .dynsbss)
  90. }
  91. }
  92. /*
  93. * Very old versions of ld do not recognize this name token; use the constant.
  94. */
  95. #define PT_GNU_EH_FRAME 0x6474e550
  96. /*
  97. * We must supply the ELF program headers explicitly to get just one
  98. * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  99. */
  100. PHDRS
  101. {
  102. text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  103. dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  104. note PT_NOTE FLAGS(4); /* PF_R */
  105. eh_frame_hdr PT_GNU_EH_FRAME;
  106. }
  107. /*
  108. * This controls what symbols we export from the DSO.
  109. */
  110. VERSION
  111. {
  112. VDSO_VERSION_STRING {
  113. global:
  114. /*
  115. * Has to be there for the kernel to find
  116. */
  117. __kernel_datapage_offset;
  118. __kernel_get_syscall_map;
  119. __kernel_gettimeofday;
  120. __kernel_clock_gettime;
  121. __kernel_clock_getres;
  122. __kernel_get_tbfreq;
  123. __kernel_sync_dicache;
  124. __kernel_sync_dicache_p5;
  125. __kernel_sigtramp_rt64;
  126. local: *;
  127. };
  128. }