entry.S 22 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899
  1. /*
  2. * Copyright (C) 2000-2003 Axis Communications AB
  3. *
  4. * Authors: Bjorn Wesen (bjornw@axis.com)
  5. * Tobias Anderberg (tobiasa@axis.com), CRISv32 port.
  6. *
  7. * Code for the system-call and fault low-level handling routines.
  8. *
  9. * NOTE: This code handles signal-recognition, which happens every time
  10. * after a timer-interrupt and after each system call.
  11. *
  12. * Stack layout in 'ret_from_system_call':
  13. * ptrace needs to have all regs on the stack.
  14. * if the order here is changed, it needs to be
  15. * updated in fork.c:copy_process, signal.c:do_signal,
  16. * ptrace.c and ptrace.h
  17. *
  18. */
  19. #include <linux/linkage.h>
  20. #include <linux/sys.h>
  21. #include <asm/unistd.h>
  22. #include <asm/errno.h>
  23. #include <asm/thread_info.h>
  24. #include <asm/asm-offsets.h>
  25. #include <hwregs/asm/reg_map_asm.h>
  26. #include <hwregs/asm/intr_vect_defs_asm.h>
  27. ;; Exported functions.
  28. .globl system_call
  29. .globl ret_from_intr
  30. .globl ret_from_fork
  31. .globl ret_from_kernel_thread
  32. .globl resume
  33. .globl multiple_interrupt
  34. .globl nmi_interrupt
  35. .globl spurious_interrupt
  36. .globl do_sigtrap
  37. .globl gdb_handle_exception
  38. .globl sys_call_table
  39. ; Check if preemptive kernel scheduling should be done.
  40. #ifdef CONFIG_PREEMPT
  41. _resume_kernel:
  42. di
  43. ; Load current task struct.
  44. movs.w -8192, $r0 ; THREAD_SIZE = 8192
  45. and.d $sp, $r0
  46. addoq +TI_preempt_count, $r0, $acr
  47. move.d [$acr], $r10 ; Preemption disabled?
  48. bne _Rexit
  49. nop
  50. _need_resched:
  51. addoq +TI_flags, $r0, $acr
  52. move.d [$acr], $r10
  53. btstq TIF_NEED_RESCHED, $r10 ; Check if need_resched is set.
  54. bpl _Rexit
  55. nop
  56. ; Do preemptive kernel scheduling.
  57. jsr preempt_schedule_irq
  58. nop
  59. ; Load new task struct.
  60. movs.w -8192, $r0 ; THREAD_SIZE = 8192.
  61. and.d $sp, $r0
  62. ; One more time with new task.
  63. ba _need_resched
  64. nop
  65. #else
  66. #define _resume_kernel _Rexit
  67. #endif
  68. ; Called at exit from fork. schedule_tail must be called to drop
  69. ; spinlock if CONFIG_PREEMPT.
  70. .type ret_from_fork,@function
  71. ret_from_fork:
  72. jsr schedule_tail
  73. nop
  74. ba ret_from_sys_call
  75. nop
  76. .size ret_from_fork, . - ret_from_fork
  77. .type ret_from_kernel_thread,@function
  78. ret_from_kernel_thread:
  79. jsr schedule_tail
  80. nop
  81. move.d $r2, $r10
  82. jsr $r1
  83. nop
  84. moveq 0, $r9 ; no syscall restarts, TYVM...
  85. ba ret_from_sys_call
  86. nop
  87. .size ret_from_kernel_thread, . - ret_from_kernel_thread
  88. .type ret_from_intr,@function
  89. ret_from_intr:
  90. ;; Check for resched if preemptive kernel, or if we're going back to
  91. ;; user-mode. This test matches the user_regs(regs) macro. Don't simply
  92. ;; test CCS since that doesn't necessarily reflect what mode we'll
  93. ;; return into.
  94. addoq +PT_ccs, $sp, $acr
  95. move.d [$acr], $r0
  96. btstq 16, $r0 ; User-mode flag.
  97. bpl _resume_kernel
  98. .size ret_from_intr, . - ret_from_intr + 2 ; +2 includes the dslot.
  99. ; Note that di below is in delay slot.
  100. .type _resume_userspace,@function
  101. _resume_userspace:
  102. di ; So need_resched and sigpending don't change.
  103. movs.w -8192, $r0 ; THREAD_SIZE == 8192
  104. and.d $sp, $r0
  105. addoq +TI_flags, $r0, $acr ; current->work
  106. move.d [$acr], $r10
  107. and.d _TIF_WORK_MASK, $r10 ; Work to be done on return?
  108. bne _work_pending
  109. nop
  110. ba _Rexit
  111. nop
  112. .size _resume_userspace, . - _resume_userspace
  113. ;; The system_call is called by a BREAK instruction, which looks pretty
  114. ;; much like any other exception.
  115. ;;
  116. ;; System calls can't be made from interrupts but we still stack ERP
  117. ;; to have a complete stack frame.
  118. ;;
  119. ;; In r9 we have the wanted syscall number. Arguments come in r10,r11,r12,
  120. ;; r13,mof,srp
  121. ;;
  122. ;; This function looks on the _surface_ like spaghetti programming, but it's
  123. ;; really designed so that the fast-path does not force cache-loading of
  124. ;; non-used instructions. Only the non-common cases cause the outlined code
  125. ;; to run..
  126. .type system_call,@function
  127. system_call:
  128. ;; Stack-frame similar to the irq heads, which is reversed in
  129. ;; ret_from_sys_call.
  130. sub.d 92, $sp ; Skip EXS and EDA.
  131. movem $r13, [$sp]
  132. move.d $sp, $r8
  133. addq 14*4, $r8
  134. move.d $acr, $r0
  135. move $srs, $r1
  136. move $mof, $r2
  137. move $spc, $r3
  138. move $ccs, $r4
  139. move $srp, $r5
  140. move $erp, $r6
  141. subq 4, $sp
  142. movem $r6, [$r8]
  143. ei ; Enable interrupts while processing syscalls.
  144. move.d $r10, [$sp]
  145. ; Set S-bit when kernel debugging to keep hardware breakpoints active.
  146. #ifdef CONFIG_ETRAX_KGDB
  147. move $ccs, $r0
  148. or.d (1<<9), $r0
  149. move $r0, $ccs
  150. #endif
  151. movs.w -ENOSYS, $r0
  152. addoq +PT_r10, $sp, $acr
  153. move.d $r0, [$acr]
  154. ;; Check if this process is syscall-traced.
  155. movs.w -8192, $r0 ; THREAD_SIZE == 8192
  156. and.d $sp, $r0
  157. addoq +TI_flags, $r0, $acr
  158. move.d [$acr], $r0
  159. btstq TIF_SYSCALL_TRACE, $r0
  160. bmi _syscall_trace_entry
  161. nop
  162. _syscall_traced:
  163. ;; Check for sanity in the requested syscall number.
  164. cmpu.w NR_syscalls, $r9
  165. bhs ret_from_sys_call
  166. lslq 2, $r9 ; Multiply by 4, in the delay slot.
  167. ;; The location on the stack for the register structure is passed as a
  168. ;; seventh argument. Some system calls need this.
  169. move.d $sp, $r0
  170. subq 4, $sp
  171. move.d $r0, [$sp]
  172. ;; The registers carrying parameters (R10-R13) are intact. The optional
  173. ;; fifth and sixth parameters is in MOF and SRP respectively. Put them
  174. ;; back on the stack.
  175. subq 4, $sp
  176. move $srp, [$sp]
  177. subq 4, $sp
  178. move $mof, [$sp]
  179. ;; Actually to the system call.
  180. addo.d +sys_call_table, $r9, $acr
  181. move.d [$acr], $acr
  182. jsr $acr
  183. nop
  184. addq 3*4, $sp ; Pop the mof, srp and regs parameters.
  185. addoq +PT_r10, $sp, $acr
  186. move.d $r10, [$acr] ; Save the return value.
  187. moveq 1, $r9 ; "Parameter" to ret_from_sys_call to
  188. ; show it was a sys call.
  189. ;; Fall through into ret_from_sys_call to return.
  190. ret_from_sys_call:
  191. ;; R9 is a parameter:
  192. ;; >= 1 from syscall
  193. ;; 0 from irq
  194. ;; Get the current task-struct pointer.
  195. movs.w -8192, $r0 ; THREAD_SIZE == 8192
  196. and.d $sp, $r0
  197. di ; Make sure need_resched and sigpending don't change.
  198. addoq +TI_flags, $r0, $acr
  199. move.d [$acr], $r1
  200. and.d _TIF_ALLWORK_MASK, $r1
  201. bne _syscall_exit_work
  202. nop
  203. .size system_call, . - system_call
  204. .type _Rexit,@function
  205. _Rexit:
  206. ;; This epilogue MUST match the prologues in multiple_interrupt, irq.h
  207. ;; and ptregs.h.
  208. addq 4, $sp ; Skip orig_r10.
  209. movem [$sp+], $r13 ; Registers R0-R13.
  210. move.d [$sp+], $acr
  211. move [$sp], $srs
  212. addq 4, $sp
  213. move [$sp+], $mof
  214. move [$sp+], $spc
  215. move [$sp+], $ccs
  216. move [$sp+], $srp
  217. move [$sp+], $erp
  218. addq 8, $sp ; Skip EXS, EDA.
  219. jump $erp
  220. rfe ; Restore condition code stack in delay-slot.
  221. .size _Rexit, . - _Rexit
  222. ;; We get here after doing a syscall if extra work might need to be done
  223. ;; perform syscall exit tracing if needed.
  224. .type _syscall_exit_work,@function
  225. _syscall_exit_work:
  226. ;; R0 contains current at this point and irq's are disabled.
  227. addoq +TI_flags, $r0, $acr
  228. move.d [$acr], $r1
  229. btstq TIF_SYSCALL_TRACE, $r1
  230. bpl _work_pending
  231. nop
  232. ei
  233. move.d $r9, $r1 ; Preserve R9.
  234. jsr do_syscall_trace
  235. nop
  236. move.d $r1, $r9
  237. ba _resume_userspace
  238. nop
  239. .size _syscall_exit_work, . - _syscall_exit_work
  240. .type _work_pending,@function
  241. _work_pending:
  242. addoq +TI_flags, $r0, $acr
  243. move.d [$acr], $r10
  244. btstq TIF_NEED_RESCHED, $r10 ; Need resched?
  245. bpl _work_notifysig ; No, must be signal/notify.
  246. nop
  247. .size _work_pending, . - _work_pending
  248. .type _work_resched,@function
  249. _work_resched:
  250. move.d $r9, $r1 ; Preserve R9.
  251. jsr schedule
  252. nop
  253. move.d $r1, $r9
  254. di
  255. addoq +TI_flags, $r0, $acr
  256. move.d [$acr], $r1
  257. and.d _TIF_WORK_MASK, $r1 ; Ignore sycall trace counter.
  258. beq _Rexit
  259. nop
  260. btstq TIF_NEED_RESCHED, $r1
  261. bmi _work_resched ; current->work.need_resched.
  262. nop
  263. .size _work_resched, . - _work_resched
  264. .type _work_notifysig,@function
  265. _work_notifysig:
  266. ;; Deal with pending signals and notify-resume requests.
  267. addoq +TI_flags, $r0, $acr
  268. move.d [$acr], $r12 ; The thread_info_flags parameter.
  269. move.d $sp, $r11 ; The regs param.
  270. jsr do_notify_resume
  271. move.d $r9, $r10 ; do_notify_resume syscall/irq param.
  272. ba _Rexit
  273. nop
  274. .size _work_notifysig, . - _work_notifysig
  275. ;; We get here as a sidetrack when we've entered a syscall with the
  276. ;; trace-bit set. We need to call do_syscall_trace and then continue
  277. ;; with the call.
  278. _syscall_trace_entry:
  279. ;; PT_r10 in the frame contains -ENOSYS as required, at this point.
  280. jsr do_syscall_trace
  281. nop
  282. ;; Now re-enter the syscall code to do the syscall itself. We need to
  283. ;; restore R9 here to contain the wanted syscall, and the other
  284. ;; parameter-bearing registers.
  285. addoq +PT_r9, $sp, $acr
  286. move.d [$acr], $r9
  287. addoq +PT_orig_r10, $sp, $acr
  288. move.d [$acr], $r10 ; PT_r10 is already -ENOSYS.
  289. addoq +PT_r11, $sp, $acr
  290. move.d [$acr], $r11
  291. addoq +PT_r12, $sp, $acr
  292. move.d [$acr], $r12
  293. addoq +PT_r13, $sp, $acr
  294. move.d [$acr], $r13
  295. addoq +PT_mof, $sp, $acr
  296. move [$acr], $mof
  297. addoq +PT_srp, $sp, $acr
  298. move [$acr], $srp
  299. ba _syscall_traced
  300. nop
  301. ;; Resume performs the actual task-switching, by switching stack
  302. ;; pointers. Input arguments are:
  303. ;;
  304. ;; R10 = prev
  305. ;; R11 = next
  306. ;; R12 = thread offset in task struct.
  307. ;;
  308. ;; Returns old current in R10.
  309. .type resume,@function
  310. resume:
  311. subq 4, $sp ; Make space for srp.
  312. add.d $r12, $r10 ; R10 = current tasks tss.
  313. addoq +THREAD_ccs, $r10, $acr
  314. move $srp, [$sp] ; Keep old/new PC on the stack.
  315. move $ccs, [$acr] ; Save IRQ enable state.
  316. di
  317. addoq +THREAD_usp, $r10, $acr
  318. subq 10*4, $sp ; Make room for R9.
  319. move $usp, [$acr] ; Save user-mode stackpointer.
  320. ;; See copy_thread for the reason why register R9 is saved.
  321. movem $r9, [$sp] ; Save non-scratch registers and R9.
  322. addoq +THREAD_ksp, $r10, $acr
  323. move.d $sp, $r10 ; Return last running task in R10.
  324. move.d $sp, [$acr] ; Save kernel SP for old task.
  325. and.d -8192, $r10 ; Get thread_info from stackpointer.
  326. addoq +TI_task, $r10, $acr
  327. add.d $r12, $r11 ; Find the new tasks tss.
  328. move.d [$acr], $r10 ; Get task.
  329. addoq +THREAD_ksp, $r11, $acr
  330. move.d [$acr], $sp ; Switch to new stackframe.
  331. addoq +THREAD_usp, $r11, $acr
  332. movem [$sp+], $r9 ; Restore non-scratch registers and R9.
  333. move [$acr], $usp ; Restore user-mode stackpointer.
  334. addoq +THREAD_ccs, $r11, $acr
  335. move.d [$sp+], $r11
  336. jump $r11 ; Restore PC.
  337. move [$acr], $ccs ; Restore IRQ enable status.
  338. .size resume, . - resume
  339. nmi_interrupt:
  340. ;; If we receive a watchdog interrupt while it is not expected, then set
  341. ;; up a canonical frame and dump register contents before dying.
  342. ;; This prologue MUST match the one in irq.h and the struct in ptregs.h!
  343. subq 12, $sp ; Skip EXS, EDA.
  344. move $nrp, [$sp]
  345. subq 4, $sp
  346. move $srp, [$sp]
  347. subq 4, $sp
  348. move $ccs, [$sp]
  349. subq 4, $sp
  350. move $spc, [$sp]
  351. subq 4, $sp
  352. move $mof, [$sp]
  353. subq 4, $sp
  354. move $srs, [$sp]
  355. subq 4, $sp
  356. move.d $acr, [$sp]
  357. subq 14*4, $sp ; Make room for R0-R13.
  358. movem $r13, [$sp] ; Push R0-R13.
  359. subq 4, $sp
  360. move.d $r10, [$sp] ; Push orig_r10.
  361. move.d REG_ADDR(intr_vect, regi_irq, r_nmi), $r0
  362. move.d [$r0], $r0
  363. btstq REG_BIT(intr_vect, r_nmi, watchdog), $r0
  364. bpl 1f
  365. nop
  366. jsr handle_watchdog_bite ; In time.c.
  367. move.d $sp, $r10 ; Pointer to registers
  368. 1: btstq REG_BIT(intr_vect, r_nmi, ext), $r0
  369. bpl 1f
  370. nop
  371. jsr handle_nmi
  372. move.d $sp, $r10 ; Pointer to registers
  373. 1: addq 4, $sp ; Skip orig_r10
  374. movem [$sp+], $r13
  375. move.d [$sp+], $acr
  376. move [$sp], $srs
  377. addq 4, $sp
  378. move [$sp+], $mof
  379. move [$sp+], $spc
  380. move [$sp+], $ccs
  381. move [$sp+], $srp
  382. move [$sp+], $nrp
  383. addq 8, $sp ; Skip EXS, EDA.
  384. jump $nrp
  385. rfn
  386. .comm cause_of_death, 4 ;; Don't declare this anywhere.
  387. spurious_interrupt:
  388. di
  389. jump hard_reset_now
  390. nop
  391. ;; This handles the case when multiple interrupts arrive at the same
  392. ;; time. Jump to the first set interrupt bit in a priotiry fashion. The
  393. ;; hardware will call the unserved interrupts after the handler
  394. ;; finishes.
  395. .type multiple_interrupt, @function
  396. multiple_interrupt:
  397. ;; This prologue MUST match the one in irq.h and the struct in ptregs.h!
  398. subq 12, $sp ; Skip EXS, EDA.
  399. move $erp, [$sp]
  400. subq 4, $sp
  401. move $srp, [$sp]
  402. subq 4, $sp
  403. move $ccs, [$sp]
  404. subq 4, $sp
  405. move $spc, [$sp]
  406. subq 4, $sp
  407. move $mof, [$sp]
  408. subq 4, $sp
  409. move $srs, [$sp]
  410. subq 4, $sp
  411. move.d $acr, [$sp]
  412. subq 14*4, $sp ; Make room for R0-R13.
  413. movem $r13, [$sp] ; Push R0-R13.
  414. subq 4, $sp
  415. move.d $r10, [$sp] ; Push orig_r10.
  416. ; Set S-bit when kernel debugging to keep hardware breakpoints active.
  417. #ifdef CONFIG_ETRAX_KGDB
  418. move $ccs, $r0
  419. or.d (1<<9), $r0
  420. move $r0, $ccs
  421. #endif
  422. jsr crisv32_do_multiple
  423. move.d $sp, $r10
  424. jump ret_from_intr
  425. nop
  426. .size multiple_interrupt, . - multiple_interrupt
  427. do_sigtrap:
  428. ;; Sigtraps the process that executed the BREAK instruction. Creates a
  429. ;; frame that Rexit expects.
  430. subq 4, $sp
  431. move $eda, [$sp]
  432. subq 4, $sp
  433. move $exs, [$sp]
  434. subq 4, $sp
  435. move $erp, [$sp]
  436. subq 4, $sp
  437. move $srp, [$sp]
  438. subq 4, $sp
  439. move $ccs, [$sp]
  440. subq 4, $sp
  441. move $spc, [$sp]
  442. subq 4, $sp
  443. move $mof, [$sp]
  444. subq 4, $sp
  445. move $srs, [$sp]
  446. subq 4, $sp
  447. move.d $acr, [$sp]
  448. di ; Need to disable irq's at this point.
  449. subq 14*4, $sp ; Make room for r0-r13.
  450. movem $r13, [$sp] ; Push the r0-r13 registers.
  451. subq 4, $sp
  452. move.d $r10, [$sp] ; Push orig_r10.
  453. movs.w -8192, $r9 ; THREAD_SIZE == 8192
  454. and.d $sp, $r9
  455. ;; thread_info as first parameter
  456. move.d $r9, $r10
  457. moveq 5, $r11 ; SIGTRAP as second argument.
  458. jsr ugdb_trap_user
  459. nop
  460. jump ret_from_intr ; Use the return routine for interrupts.
  461. nop
  462. gdb_handle_exception:
  463. subq 4, $sp
  464. move.d $r0, [$sp]
  465. #ifdef CONFIG_ETRAX_KGDB
  466. move $ccs, $r0 ; U-flag not affected by previous insns.
  467. btstq 16, $r0 ; Test the U-flag.
  468. bmi _ugdb_handle_exception ; Go to user mode debugging.
  469. nop ; Empty delay-slot (cannot pop R0 here).
  470. ba kgdb_handle_exception ; Go to kernel debugging.
  471. move.d [$sp+], $r0 ; Restore R0 in delay slot.
  472. #endif
  473. _ugdb_handle_exception:
  474. ba do_sigtrap ; SIGTRAP the offending process.
  475. move.d [$sp+], $r0 ; Restore R0 in delay slot.
  476. .data
  477. .section .rodata,"a"
  478. sys_call_table:
  479. .long sys_restart_syscall ; 0 - old "setup()" system call, used
  480. ; for restarting.
  481. .long sys_exit
  482. .long sys_fork
  483. .long sys_read
  484. .long sys_write
  485. .long sys_open /* 5 */
  486. .long sys_close
  487. .long sys_waitpid
  488. .long sys_creat
  489. .long sys_link
  490. .long sys_unlink /* 10 */
  491. .long sys_execve
  492. .long sys_chdir
  493. .long sys_time
  494. .long sys_mknod
  495. .long sys_chmod /* 15 */
  496. .long sys_lchown16
  497. .long sys_ni_syscall /* old break syscall holder */
  498. .long sys_stat
  499. .long sys_lseek
  500. .long sys_getpid /* 20 */
  501. .long sys_mount
  502. .long sys_oldumount
  503. .long sys_setuid16
  504. .long sys_getuid16
  505. .long sys_stime /* 25 */
  506. .long sys_ptrace
  507. .long sys_alarm
  508. .long sys_fstat
  509. .long sys_pause
  510. .long sys_utime /* 30 */
  511. .long sys_ni_syscall /* old stty syscall holder */
  512. .long sys_ni_syscall /* old gtty syscall holder */
  513. .long sys_access
  514. .long sys_nice
  515. .long sys_ni_syscall /* 35 old ftime syscall holder */
  516. .long sys_sync
  517. .long sys_kill
  518. .long sys_rename
  519. .long sys_mkdir
  520. .long sys_rmdir /* 40 */
  521. .long sys_dup
  522. .long sys_pipe
  523. .long sys_times
  524. .long sys_ni_syscall /* old prof syscall holder */
  525. .long sys_brk /* 45 */
  526. .long sys_setgid16
  527. .long sys_getgid16
  528. .long sys_signal
  529. .long sys_geteuid16
  530. .long sys_getegid16 /* 50 */
  531. .long sys_acct
  532. .long sys_umount /* recycled never used phys( */
  533. .long sys_ni_syscall /* old lock syscall holder */
  534. .long sys_ioctl
  535. .long sys_fcntl /* 55 */
  536. .long sys_ni_syscall /* old mpx syscall holder */
  537. .long sys_setpgid
  538. .long sys_ni_syscall /* old ulimit syscall holder */
  539. .long sys_ni_syscall /* old sys_olduname holder */
  540. .long sys_umask /* 60 */
  541. .long sys_chroot
  542. .long sys_ustat
  543. .long sys_dup2
  544. .long sys_getppid
  545. .long sys_getpgrp /* 65 */
  546. .long sys_setsid
  547. .long sys_sigaction
  548. .long sys_sgetmask
  549. .long sys_ssetmask
  550. .long sys_setreuid16 /* 70 */
  551. .long sys_setregid16
  552. .long sys_sigsuspend
  553. .long sys_sigpending
  554. .long sys_sethostname
  555. .long sys_setrlimit /* 75 */
  556. .long sys_old_getrlimit
  557. .long sys_getrusage
  558. .long sys_gettimeofday
  559. .long sys_settimeofday
  560. .long sys_getgroups16 /* 80 */
  561. .long sys_setgroups16
  562. .long sys_select /* was old_select in Linux/E100 */
  563. .long sys_symlink
  564. .long sys_lstat
  565. .long sys_readlink /* 85 */
  566. .long sys_uselib
  567. .long sys_swapon
  568. .long sys_reboot
  569. .long sys_old_readdir
  570. .long sys_old_mmap /* 90 */
  571. .long sys_munmap
  572. .long sys_truncate
  573. .long sys_ftruncate
  574. .long sys_fchmod
  575. .long sys_fchown16 /* 95 */
  576. .long sys_getpriority
  577. .long sys_setpriority
  578. .long sys_ni_syscall /* old profil syscall holder */
  579. .long sys_statfs
  580. .long sys_fstatfs /* 100 */
  581. .long sys_ni_syscall /* sys_ioperm in i386 */
  582. .long sys_socketcall
  583. .long sys_syslog
  584. .long sys_setitimer
  585. .long sys_getitimer /* 105 */
  586. .long sys_newstat
  587. .long sys_newlstat
  588. .long sys_newfstat
  589. .long sys_ni_syscall /* old sys_uname holder */
  590. .long sys_ni_syscall /* sys_iopl in i386 */
  591. .long sys_vhangup
  592. .long sys_ni_syscall /* old "idle" system call */
  593. .long sys_ni_syscall /* vm86old in i386 */
  594. .long sys_wait4
  595. .long sys_swapoff /* 115 */
  596. .long sys_sysinfo
  597. .long sys_ipc
  598. .long sys_fsync
  599. .long sys_sigreturn
  600. .long sys_clone /* 120 */
  601. .long sys_setdomainname
  602. .long sys_newuname
  603. .long sys_ni_syscall /* sys_modify_ldt */
  604. .long sys_adjtimex
  605. .long sys_mprotect /* 125 */
  606. .long sys_sigprocmask
  607. .long sys_ni_syscall /* old "create_module" */
  608. .long sys_init_module
  609. .long sys_delete_module
  610. .long sys_ni_syscall /* 130: old "get_kernel_syms" */
  611. .long sys_quotactl
  612. .long sys_getpgid
  613. .long sys_fchdir
  614. .long sys_bdflush
  615. .long sys_sysfs /* 135 */
  616. .long sys_personality
  617. .long sys_ni_syscall /* for afs_syscall */
  618. .long sys_setfsuid16
  619. .long sys_setfsgid16
  620. .long sys_llseek /* 140 */
  621. .long sys_getdents
  622. .long sys_select
  623. .long sys_flock
  624. .long sys_msync
  625. .long sys_readv /* 145 */
  626. .long sys_writev
  627. .long sys_getsid
  628. .long sys_fdatasync
  629. .long sys_sysctl
  630. .long sys_mlock /* 150 */
  631. .long sys_munlock
  632. .long sys_mlockall
  633. .long sys_munlockall
  634. .long sys_sched_setparam
  635. .long sys_sched_getparam /* 155 */
  636. .long sys_sched_setscheduler
  637. .long sys_sched_getscheduler
  638. .long sys_sched_yield
  639. .long sys_sched_get_priority_max
  640. .long sys_sched_get_priority_min /* 160 */
  641. .long sys_sched_rr_get_interval
  642. .long sys_nanosleep
  643. .long sys_mremap
  644. .long sys_setresuid16
  645. .long sys_getresuid16 /* 165 */
  646. .long sys_ni_syscall /* sys_vm86 */
  647. .long sys_ni_syscall /* Old sys_query_module */
  648. .long sys_poll
  649. .long sys_ni_syscall /* Old nfsservctl */
  650. .long sys_setresgid16 /* 170 */
  651. .long sys_getresgid16
  652. .long sys_prctl
  653. .long sys_rt_sigreturn
  654. .long sys_rt_sigaction
  655. .long sys_rt_sigprocmask /* 175 */
  656. .long sys_rt_sigpending
  657. .long sys_rt_sigtimedwait
  658. .long sys_rt_sigqueueinfo
  659. .long sys_rt_sigsuspend
  660. .long sys_pread64 /* 180 */
  661. .long sys_pwrite64
  662. .long sys_chown16
  663. .long sys_getcwd
  664. .long sys_capget
  665. .long sys_capset /* 185 */
  666. .long sys_sigaltstack
  667. .long sys_sendfile
  668. .long sys_ni_syscall /* streams1 */
  669. .long sys_ni_syscall /* streams2 */
  670. .long sys_vfork /* 190 */
  671. .long sys_getrlimit
  672. .long sys_mmap2
  673. .long sys_truncate64
  674. .long sys_ftruncate64
  675. .long sys_stat64 /* 195 */
  676. .long sys_lstat64
  677. .long sys_fstat64
  678. .long sys_lchown
  679. .long sys_getuid
  680. .long sys_getgid /* 200 */
  681. .long sys_geteuid
  682. .long sys_getegid
  683. .long sys_setreuid
  684. .long sys_setregid
  685. .long sys_getgroups /* 205 */
  686. .long sys_setgroups
  687. .long sys_fchown
  688. .long sys_setresuid
  689. .long sys_getresuid
  690. .long sys_setresgid /* 210 */
  691. .long sys_getresgid
  692. .long sys_chown
  693. .long sys_setuid
  694. .long sys_setgid
  695. .long sys_setfsuid /* 215 */
  696. .long sys_setfsgid
  697. .long sys_pivot_root
  698. .long sys_mincore
  699. .long sys_madvise
  700. .long sys_getdents64 /* 220 */
  701. .long sys_fcntl64
  702. .long sys_ni_syscall /* reserved for TUX */
  703. .long sys_ni_syscall
  704. .long sys_gettid
  705. .long sys_readahead /* 225 */
  706. .long sys_setxattr
  707. .long sys_lsetxattr
  708. .long sys_fsetxattr
  709. .long sys_getxattr
  710. .long sys_lgetxattr /* 230 */
  711. .long sys_fgetxattr
  712. .long sys_listxattr
  713. .long sys_llistxattr
  714. .long sys_flistxattr
  715. .long sys_removexattr /* 235 */
  716. .long sys_lremovexattr
  717. .long sys_fremovexattr
  718. .long sys_tkill
  719. .long sys_sendfile64
  720. .long sys_futex /* 240 */
  721. .long sys_sched_setaffinity
  722. .long sys_sched_getaffinity
  723. .long sys_ni_syscall /* sys_set_thread_area */
  724. .long sys_ni_syscall /* sys_get_thread_area */
  725. .long sys_io_setup /* 245 */
  726. .long sys_io_destroy
  727. .long sys_io_getevents
  728. .long sys_io_submit
  729. .long sys_io_cancel
  730. .long sys_fadvise64 /* 250 */
  731. .long sys_ni_syscall
  732. .long sys_exit_group
  733. .long sys_lookup_dcookie
  734. .long sys_epoll_create
  735. .long sys_epoll_ctl /* 255 */
  736. .long sys_epoll_wait
  737. .long sys_remap_file_pages
  738. .long sys_set_tid_address
  739. .long sys_timer_create
  740. .long sys_timer_settime /* 260 */
  741. .long sys_timer_gettime
  742. .long sys_timer_getoverrun
  743. .long sys_timer_delete
  744. .long sys_clock_settime
  745. .long sys_clock_gettime /* 265 */
  746. .long sys_clock_getres
  747. .long sys_clock_nanosleep
  748. .long sys_statfs64
  749. .long sys_fstatfs64
  750. .long sys_tgkill /* 270 */
  751. .long sys_utimes
  752. .long sys_fadvise64_64
  753. .long sys_ni_syscall /* sys_vserver */
  754. .long sys_ni_syscall /* sys_mbind */
  755. .long sys_ni_syscall /* 275 sys_get_mempolicy */
  756. .long sys_ni_syscall /* sys_set_mempolicy */
  757. .long sys_mq_open
  758. .long sys_mq_unlink
  759. .long sys_mq_timedsend
  760. .long sys_mq_timedreceive /* 280 */
  761. .long sys_mq_notify
  762. .long sys_mq_getsetattr
  763. .long sys_ni_syscall /* reserved for kexec */
  764. .long sys_waitid
  765. .long sys_ni_syscall /* 285 */ /* available */
  766. .long sys_add_key
  767. .long sys_request_key
  768. .long sys_keyctl
  769. .long sys_ioprio_set
  770. .long sys_ioprio_get /* 290 */
  771. .long sys_inotify_init
  772. .long sys_inotify_add_watch
  773. .long sys_inotify_rm_watch
  774. .long sys_migrate_pages
  775. .long sys_openat /* 295 */
  776. .long sys_mkdirat
  777. .long sys_mknodat
  778. .long sys_fchownat
  779. .long sys_futimesat
  780. .long sys_fstatat64 /* 300 */
  781. .long sys_unlinkat
  782. .long sys_renameat
  783. .long sys_linkat
  784. .long sys_symlinkat
  785. .long sys_readlinkat /* 305 */
  786. .long sys_fchmodat
  787. .long sys_faccessat
  788. .long sys_pselect6
  789. .long sys_ppoll
  790. .long sys_unshare /* 310 */
  791. .long sys_set_robust_list
  792. .long sys_get_robust_list
  793. .long sys_splice
  794. .long sys_sync_file_range
  795. .long sys_tee /* 315 */
  796. .long sys_vmsplice
  797. .long sys_move_pages
  798. .long sys_getcpu
  799. .long sys_epoll_pwait
  800. .long sys_utimensat /* 320 */
  801. .long sys_signalfd
  802. .long sys_timerfd_create
  803. .long sys_eventfd
  804. .long sys_fallocate
  805. .long sys_timerfd_settime /* 325 */
  806. .long sys_timerfd_gettime
  807. .long sys_signalfd4
  808. .long sys_eventfd2
  809. .long sys_epoll_create1
  810. .long sys_dup3 /* 330 */
  811. .long sys_pipe2
  812. .long sys_inotify_init1
  813. .long sys_preadv
  814. .long sys_pwritev
  815. .long sys_setns /* 335 */
  816. /*
  817. * NOTE!! This doesn't have to be exact - we just have
  818. * to make sure we have _enough_ of the "sys_ni_syscall"
  819. * entries. Don't panic if you notice that this hasn't
  820. * been shrunk every time we add a new system call.
  821. */
  822. .rept NR_syscalls - (.-sys_call_table) / 4
  823. .long sys_ni_syscall
  824. .endr