sleep.S 3.4 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191
  1. /*
  2. * arch/sh/kernel/cpu/sh4a/sleep-sh_mobile.S
  3. *
  4. * Sleep mode and Standby modes support for SuperH Mobile
  5. *
  6. * Copyright (C) 2009 Magnus Damm
  7. *
  8. * This file is subject to the terms and conditions of the GNU General Public
  9. * License. See the file "COPYING" in the main directory of this archive
  10. * for more details.
  11. */
  12. #include <linux/sys.h>
  13. #include <linux/errno.h>
  14. #include <linux/linkage.h>
  15. #include <asm/asm-offsets.h>
  16. #include <asm/suspend.h>
  17. /* manage self-refresh and enter standby mode.
  18. * this code will be copied to on-chip memory and executed from there.
  19. */
  20. .balign 4096,0,4096
  21. ENTRY(sh_mobile_standby)
  22. mov r4, r0
  23. tst #SUSP_SH_SF, r0
  24. bt skip_set_sf
  25. #ifdef CONFIG_CPU_SUBTYPE_SH7724
  26. /* DBSC: put memory in self-refresh mode */
  27. mov.l dben_reg, r4
  28. mov.l dben_data0, r1
  29. mov.l r1, @r4
  30. mov.l dbrfpdn0_reg, r4
  31. mov.l dbrfpdn0_data0, r1
  32. mov.l r1, @r4
  33. mov.l dbcmdcnt_reg, r4
  34. mov.l dbcmdcnt_data0, r1
  35. mov.l r1, @r4
  36. mov.l dbcmdcnt_reg, r4
  37. mov.l dbcmdcnt_data1, r1
  38. mov.l r1, @r4
  39. mov.l dbrfpdn0_reg, r4
  40. mov.l dbrfpdn0_data1, r1
  41. mov.l r1, @r4
  42. #else
  43. /* SBSC: disable power down and put in self-refresh mode */
  44. mov.l 1f, r4
  45. mov.l 2f, r1
  46. mov.l @r4, r2
  47. or r1, r2
  48. mov.l 3f, r3
  49. and r3, r2
  50. mov.l r2, @r4
  51. #endif
  52. skip_set_sf:
  53. tst #SUSP_SH_SLEEP, r0
  54. bt test_standby
  55. /* set mode to "sleep mode" */
  56. bra do_sleep
  57. mov #0x00, r1
  58. test_standby:
  59. tst #SUSP_SH_STANDBY, r0
  60. bt test_rstandby
  61. /* set mode to "software standby mode" */
  62. bra do_sleep
  63. mov #0x80, r1
  64. test_rstandby:
  65. tst #SUSP_SH_RSTANDBY, r0
  66. bt test_ustandby
  67. /* set mode to "r-standby mode" */
  68. bra do_sleep
  69. mov #0x20, r1
  70. test_ustandby:
  71. tst #SUSP_SH_USTANDBY, r0
  72. bt done_sleep
  73. /* set mode to "u-standby mode" */
  74. mov #0x10, r1
  75. /* fall-through */
  76. do_sleep:
  77. /* setup and enter selected standby mode */
  78. mov.l 5f, r4
  79. mov.l r1, @r4
  80. sleep
  81. done_sleep:
  82. /* reset standby mode to sleep mode */
  83. mov.l 5f, r4
  84. mov #0x00, r1
  85. mov.l r1, @r4
  86. tst #SUSP_SH_SF, r0
  87. bt skip_restore_sf
  88. #ifdef CONFIG_CPU_SUBTYPE_SH7724
  89. /* DBSC: put memory in auto-refresh mode */
  90. mov.l dbrfpdn0_reg, r4
  91. mov.l dbrfpdn0_data0, r1
  92. mov.l r1, @r4
  93. /* sleep 140 ns */
  94. nop
  95. nop
  96. nop
  97. nop
  98. mov.l dbcmdcnt_reg, r4
  99. mov.l dbcmdcnt_data0, r1
  100. mov.l r1, @r4
  101. mov.l dbcmdcnt_reg, r4
  102. mov.l dbcmdcnt_data1, r1
  103. mov.l r1, @r4
  104. mov.l dben_reg, r4
  105. mov.l dben_data1, r1
  106. mov.l r1, @r4
  107. mov.l dbrfpdn0_reg, r4
  108. mov.l dbrfpdn0_data2, r1
  109. mov.l r1, @r4
  110. #else
  111. /* SBSC: set auto-refresh mode */
  112. mov.l 1f, r4
  113. mov.l @r4, r2
  114. mov.l 4f, r3
  115. and r3, r2
  116. mov.l r2, @r4
  117. mov.l 6f, r4
  118. mov.l 7f, r1
  119. mov.l 8f, r2
  120. mov.l @r4, r3
  121. mov #-1, r4
  122. add r4, r3
  123. or r2, r3
  124. mov.l r3, @r1
  125. #endif
  126. skip_restore_sf:
  127. rts
  128. nop
  129. .balign 4
  130. #ifdef CONFIG_CPU_SUBTYPE_SH7724
  131. dben_reg: .long 0xfd000010 /* DBEN */
  132. dben_data0: .long 0
  133. dben_data1: .long 1
  134. dbrfpdn0_reg: .long 0xfd000040 /* DBRFPDN0 */
  135. dbrfpdn0_data0: .long 0
  136. dbrfpdn0_data1: .long 1
  137. dbrfpdn0_data2: .long 0x00010000
  138. dbcmdcnt_reg: .long 0xfd000014 /* DBCMDCNT */
  139. dbcmdcnt_data0: .long 2
  140. dbcmdcnt_data1: .long 4
  141. #else
  142. 1: .long 0xfe400008 /* SDCR0 */
  143. 2: .long 0x00000400
  144. 3: .long 0xffff7fff
  145. 4: .long 0xfffffbff
  146. #endif
  147. 5: .long 0xa4150020 /* STBCR */
  148. 6: .long 0xfe40001c /* RTCOR */
  149. 7: .long 0xfe400018 /* RTCNT */
  150. 8: .long 0xa55a0000
  151. /* interrupt vector @ 0x600 */
  152. .balign 0x400,0,0x400
  153. .long 0xdeadbeef
  154. .balign 0x200,0,0x200
  155. /* sh7722 will end up here in sleep mode */
  156. rte
  157. nop
  158. sh_mobile_standby_end:
  159. ENTRY(sh_mobile_standby_size)
  160. .long sh_mobile_standby_end - sh_mobile_standby